100 DATA 112211,0,12,2111,2121,211,1,1121,221,1111,11,1222,212,1211,22,21,222
110 DATA 1221,2212,121,111,2,112,1112,122,2112,2122,2211,212212
120 DATA 12121,111212,1111111,221122,21112,121212,21121,22222
130 DATA 12222,11222,11122,11112,11111,21111,22111,22211,22221,222111,212121
140 DATA 162,6,32,255,233,232,224,25,208,248,96
150 AL$="ABCDEFGHIJKLMNOPQRSTUVWXYZ1234567890?,./:;-(":D$(1)="[187]":D$(2)="[162][187]"
160 DIMC(91,7),C$(91):CR$=""
170 B=63:E=90:GOSUB180:B=40:E=59:GOSUB180:GOTO200
180 FORA=BTOE:READL$:FORC=1TOLEN(L$):C(A,C)=VAL(MID$(L$,C,1))
190 C$(A)=C$(A)+D$(C(A,C)):NEXT:NEXT:RETURN
200 FORAD=828TO838:READN:POKEAD,N:NEXT
210 READLB$(Q):IFLB$(Q)<>"X"THENQ=Q+1:GOTO210
220 POKE54277,9:POKE54278,144:POKE54274,0:POKE54275,8:POKE54296,15
230 POKE53280,6:POKE53281,0:PRINT"[147][151]                   [180][146][185][162]"
240 PRINT"             [205][162][162] [190][190] [215]  [163] [146][185][163][146][192]"
250 PRINT"          [223]                   "
260 PRINT"[154]     [162][187][187][187][162][187][187][187][162][187][187][187][162][187][187][187][162][187][187][187][162][187][187][187][162][187][187][187][162][187][153]":M$="INTERNATIONAL MORSE CODE"
270 F$(0)="[151][215][146]":F$(1)="[209]"
280 S(1)=1:S(2)=3:TM=40:TT$=M$:IFFLTHENPRINTTAB(8)M$:GOTO400
290 FORL=1TO24:GOSUB300:PRINTCR$;"[145][153]";TAB(7+L);ML$:NEXT:FL=1:GOTO400
300 ML$=MID$(M$,L,1):S(0)=2:S=0:POKE54272,74:POKE54273,42
310 S=S+1:F=1:T=C(ASC(ML$),S):IFTTHEN340
320 F=0:IFML$=" "THENS(0)=4
330 GOTO350
340 PRINTF$(F):POKE54276,65
350 FORDUR=1TOTM*S(T):NEXT:POKE54276,64:PRINTF$(0)
360 FORRS=1TOTM:NEXT:IFTTHEN310
370 RETURN
400 PRINTCR$;TAB(17);"[158] MENU ":PRINTTAB(14)"1. CODE CHART"
410 PRINTTAB(14)"2. RECEIVING":PRINTTAB(14)"3. SENDING"
420 GETA$:IFA$<"1"ORA$>"3"THEN420
430 ONVAL(A$)GOTO440,650,900
440 T$="[147][153]        "+M$+"":PRINTT$"":M$=AL$:FORL=65TO77:N=0
450 IFL<75THENN=ASC(MID$(M$,L-38,1))
460 PRINT" ";CHR$(L);" ";C$(L);TAB(14);CHR$(L+13);" ";C$(L+13);
470 PRINTTAB(27);CHR$(N);" ";C$(N):NEXT
480 POKE214,22:PRINT:PRINT"  [159]<<<  1.NEXT   2.REVIEW   3.MENU  >>>"
490 GETA$:IFA$<"1"ORA$>"3"THEN490
500 ONVAL(A$)GOTO550,510,230
510 F$(0)="                     ":TM=75:B=0:J=1:K=13:GOSUB530:B=13:K=26
520 GOSUB530:B=26:K=36:GOSUB530:GOTO490
530 FORL=JTOK:C=4:GOSUB540:GOSUB300:C=13:GOSUB540:B=B+40:NEXT:J=J+13:RETURN
540 FORP=BTOB+11:POKE55497+P,C:NEXT:RETURN
550 PRINTT$:FORL=37TO40:A1=ASC(MID$(AL$,L,1)):A2=ASC(MID$(AL$,L+4,1))
560 PRINTTAB(5);CHR$(A1);" ";C$(A1);TAB(22);CHR$(A2);" ";C$(A2):PRINT:NEXT
570 PRINTTAB(5)"WAIT (L)           "+C$(76)
580 PRINTTAB(5)"INVITE TO XMIT (K) "+C$(75)
590 PRINTTAB(5)"END OF MESSAGE     "+C$(41)
600 PRINTTAB(5)"END OF WORK        "+C$(42)
610 PRINTTAB(5)"ERROR              "+C$(43)
620 PRINT"    [159]<<<  PRESS ANY KEY FOR MENU  >>>"
630 GETA$:IFA$=""THEN630
640 GOTO230
650 SYS828:PRINTCR$;"[145][153]";TAB(8);TT$
660 PRINTTAB(14);"[158] RECEIVE MENU "
670 PRINTTAB(12)"1. RNDM CHARACTERS":PRINTTAB(12)"2. LIBRARY MESSAGE"
680 PRINTTAB(12)"3. INPUT MESSAGE":PRINTTAB(12)"4. MAIN MENU"
690 GETA$:IFA$<"1"ORA$>"4"THEN690
700 ONVAL(A$)GOTO710,800,810,230
710 M$=AL$:TM=75
720 SYS828:POKE198,0:L=INT(RND(.)*43+1):GOSUB300:PRINTCR$;TAB(20);"[158][166]"
730 GETA$:IFA$=""THEN730
740 PRINTCR$;TAB(20);A$
750 C$=ML$+"  "+C$(ASC(ML$)):PRINTTAB(20-LEN(C$)/2);"[153]";C$
760 POKE214,21:PRINT:PRINTTAB(7);"[159]<<<  CONTINUE OR MENU  >>>"
770 GETA$:IFA$=""THEN770
780 IFA$="M"THEN650
790 GOTO720
800 L=INT(RND(.)*Q):M$=LB$(L):GOTO820
810 SYS828:PRINTCR$:INPUT" [153]MESSAGE";M$
820 SYS828:PRINTCR$:INPUT" [153]WORDS PER MINUTE";T:TM=700/T
830 PRINTTAB(5)"[158]<<< PRESS ANY KEY TO BEGIN >>>"
840 GETA$:IFA$=""THEN840
850 SYS828:FORL=1TOLEN(M$):GOSUB300
860 PRINTCR$;TAB(L+1);:IFASC(ML$)>32THENPRINT"[157][158][218]"
870 NEXT:SYS828:PRINTCR$;M$:POKE214,20:PRINT
880 PRINT"    [159]<<<  PRESS ANY KEY FOR MENU  >>>"
890 GETA$:IFA$=""THEN890
895 GOTO650
900 SYS828:PRINTCR$;TAB(14);"BEGIN SENDING":T=0
910 POKE214,21:PRINT:PRINTTAB(7);"[159]<<< PRESS 'M' FOR MENU >>>":RW$="":R=10
920 L=18:M$="":GETA$:IFA$="M"THEN230
930 IFA$=""THEN920
940 PRINTCR$;TAB(14);"              ":IFTI-D>30THENT=T+1
950 D=TI:PRINTF$(1):POKE54276,65
960 IFPEEK(197)<>64THEN960
970 POKE54276,64:PRINTF$(0):K=2:IFTI-D<8THENK=1
980 PRINTCR$;TAB(L);"[158]";D$(K):L=L+K:M$=M$+D$(K):D=TI
990 GETA$:IFA$<>""THEN950
1000 IFTI-D<15THEN990
1010 FORC=44TO90:IFC$(C)<>M$THENNEXT:C=42
1020 POKE198,0:PRINTCR$;RW$;TAB(T);CHR$(C):T=T+1:D=TI:IFT<37THEN920
1030 T=1:RW$=RW$+"":R=R+1:IFR<20THEN920
1040 GOTO900
5000 DATA NO ONE KNOWS THEIR LIMITATIONS UNTIL THEY TRY
5010 DATA "EVERYONE DESIRES TO LIVE LONG, BUT NO ONE DESIRES TO BE OLD."
5020 DATA "LIKE OUR SHADOWS, OUR WISHES LENGTHEN AS OUR SUN SETS"
5030 DATA IT IS BEST NOT TO SWAP HORSES WHEN CROSSING A STREAM
5040 DATA "ALL THINGS THAT ARE, ARE WITH MORE SPIRIT CHASED THAN ENJOYED."
5050 DATA "EXPERIENCE IS THE BEST TEACHER, EXCEPT THAT THE TUITION IS COSTLY."
5060 DATA X